MQL4MQL5 テクニカル指標
iRSI()
- できること
- RSI（相対力指数）の値を取得する
- 対応
- MQL4・MQL5
iRSI() とは
RSI（相対力指数）を計算する関数です。0〜100 の値で、一般に 70 以上が買われすぎ、30 以下が売られすぎの目安とされます。MQL4 では値が直接返り、MQL5 ではハンドルが返ります。
iRSI() の書式と引数
MQL4 の場合MT4
double iRSI(
string symbol,
int timeframe,
int period,
int applied_price,
int shift
)| 引数 | 型 | 省略時 | 説明 |
|---|---|---|---|
symbol | string | 必須 | 銘柄名。チャートの銘柄なら _Symbol（NULL も可）。 |
timeframe | int | 必須 | 時間足。0 または PERIOD_CURRENT でチャートの時間足。 |
period | int | 必須 | RSI の期間（よく使われるのは 14）。 |
applied_price | int | 必須 | 計算に使う価格。PRICE_CLOSE（終値）、PRICE_OPEN、PRICE_HIGH、PRICE_LOW、PRICE_MEDIAN（(高値+安値)/2）、PRICE_TYPICAL など。MQL5 では、別のインジケーターのハンドルを渡して、そのインジケーターの値をもとに計算させることもできます（そのため型は int です）。 |
shift | int | 必須 | 値を取得するバーの位置。0 が現在（未確定）のバー、1 がひとつ前の確定したバー。 |
戻り値（MQL4）
RSI の値（0〜100）。
MQL5 の場合MT5
int iRSI(
string symbol,
ENUM_TIMEFRAMES period,
int ma_period,
int applied_price
)| 引数 | 型 | 省略時 | 説明 |
|---|---|---|---|
symbol | string | 必須 | 銘柄名。チャートの銘柄なら _Symbol（NULL も可）。 |
period | ENUM_TIMEFRAMES | 必須 | 時間足。PERIOD_CURRENT でチャートの時間足。 |
ma_period | int | 必須 | RSI の期間（よく使われるのは 14）。 |
applied_price | int | 必須 | 計算に使う価格。PRICE_CLOSE（終値）、PRICE_OPEN、PRICE_HIGH、PRICE_LOW、PRICE_MEDIAN（(高値+安値)/2）、PRICE_TYPICAL など。MQL5 では、別のインジケーターのハンドルを渡して、そのインジケーターの値をもとに計算させることもできます（そのため型は int です）。 |
戻り値（MQL5）
インジケーターのハンドル。失敗したら INVALID_HANDLE。
iRSI() の使い方（コード例）
MQL4
double rsi = iRSI(_Symbol, 0, 14, PRICE_CLOSE, 1);
if(rsi < 30) Print("売られすぎ RSI=", rsi);
else if(rsi > 70) Print("買われすぎ RSI=", rsi);MQL5
int hRsi = INVALID_HANDLE;
int OnInit()
{
hRsi = iRSI(_Symbol, PERIOD_CURRENT, 14, PRICE_CLOSE);
return hRsi == INVALID_HANDLE ? INIT_FAILED : INIT_SUCCEEDED;
}
void OnTick()
{
double rsi[];
if(CopyBuffer(hRsi, 0, 1, 1, rsi) < 1) return; // 1本前の値
if(rsi[0] < 30) Print("売られすぎ RSI=", rsi[0]);
else if(rsi[0] > 70) Print("買われすぎ RSI=", rsi[0]);
}OnTick()・OnStart() などの関数の中に書いて使う例です。MetaEditor でコンパイルできることを確認済みです。
iRSI() の注意点
- MQL5 では値ではなく「ハンドル」（インジケーターの番号）が返ります。ハンドルは OnInit() で1回だけ作り、OnTick() などで CopyBuffer() を使って値を読み出します。毎ティック作り直すと動作が重くなります。
MQL4 と MQL5 の違い
MQL4 は iRSI(…, shift) で値を直接取得、MQL5 はハンドルを作って CopyBuffer() で取得します。MQL5 の iRSI() には shift の引数がありません。
