MQLでRSI の買われすぎ・売られすぎを判定する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// RSI が 30 を上抜け→買いサイン、70 を下抜け→売りサインのアラートを出す EA（MT4）
input int    InpPeriod = 14;   // RSI の期間
input double InpLow    = 30;   // 売られすぎの水準
input double InpHigh   = 70;   // 買われすぎの水準

datetime lastBar = 0;

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnTick()
{
   datetime t = iTime(_Symbol, PERIOD_CURRENT, 0);
   if(t == lastBar) return;
   lastBar = t;

   double r1 = iRSI(_Symbol, 0, InpPeriod, PRICE_CLOSE, 1);
   double r2 = iRSI(_Symbol, 0, InpPeriod, PRICE_CLOSE, 2);

   if(r2 <= InpLow && r1 > InpLow)
      Alert(_Symbol, " RSI 買いサイン（", DoubleToString(r1, 1), "）");
   if(r2 >= InpHigh && r1 < InpHigh)
      Alert(_Symbol, " RSI 売りサイン（", DoubleToString(r1, 1), "）");
}

MQL5（MT5）コードをコピー

// RSI が 30 を上抜け→買いサイン、70 を下抜け→売りサインのアラートを出す EA（MT5）
input int    InpPeriod = 14;   // RSI の期間
input double InpLow    = 30;   // 売られすぎの水準
input double InpHigh   = 70;   // 買われすぎの水準

int      hRsi = INVALID_HANDLE;
datetime lastBar = 0;

int OnInit()
{
   hRsi = iRSI(_Symbol, PERIOD_CURRENT, InpPeriod, PRICE_CLOSE);
   return hRsi == INVALID_HANDLE ? INIT_FAILED : INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   IndicatorRelease(hRsi);
}

void OnTick()
{
   datetime t = iTime(_Symbol, PERIOD_CURRENT, 0);
   if(t == lastBar) return;

   double r[];
   ArraySetAsSeries(r, true);   // r[0]=1本前、r[1]=2本前
   if(CopyBuffer(hRsi, 0, 1, 2, r) < 2) return;
   lastBar = t;

   if(r[1] <= InpLow && r[0] > InpLow)
      Alert(_Symbol, " RSI 買いサイン（", DoubleToString(r[0], 1), "）");
   if(r[1] >= InpHigh && r[0] < InpHigh)
      Alert(_Symbol, " RSI 売りサイン（", DoubleToString(r[0], 1), "）");
}