MQLでゴールデンクロス・デッドクロスを判定して売買する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// ゴールデンクロスで買い・デッドクロスで売り（ドテン）の EA（MT4）
input int    InpFast  = 5;      // 短期 MA の期間
input int    InpSlow  = 20;     // 長期 MA の期間
input double InpLots  = 0.1;    // ロット
input int    InpMagic = 1001;   // マジックナンバー

datetime lastBar = 0;

int OnInit()
{
   if(InpFast >= InpSlow) return INIT_PARAMETERS_INCORRECT;
   return INIT_SUCCEEDED;
}

// この EA のポジションを、指定した種類だけ決済する
void ClosePositions(int type)
{
   for(int i = OrdersTotal() - 1; i >= 0; i--)
   {
      if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;
      if(OrderSymbol() != _Symbol || OrderMagicNumber() != InpMagic || OrderType() != type) continue;
      if(!OrderClose(OrderTicket(), OrderLots(), OrderClosePrice(), 30))
         Print("決済失敗 error=", GetLastError());
   }
}

int CountPositions(int type)
{
   int n = 0;
   for(int i = OrdersTotal() - 1; i >= 0; i--)
      if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES) && OrderSymbol() == _Symbol
         && OrderMagicNumber() == InpMagic && OrderType() == type)
         n++;
   return n;
}

void OnTick()
{
   // 新しい足ができたときだけ判定する
   datetime t = iTime(_Symbol, PERIOD_CURRENT, 0);
   if(t == lastBar) return;
   lastBar = t;

   double fast1 = iMA(_Symbol, 0, InpFast, 0, MODE_SMA, PRICE_CLOSE, 1);
   double fast2 = iMA(_Symbol, 0, InpFast, 0, MODE_SMA, PRICE_CLOSE, 2);
   double slow1 = iMA(_Symbol, 0, InpSlow, 0, MODE_SMA, PRICE_CLOSE, 1);
   double slow2 = iMA(_Symbol, 0, InpSlow, 0, MODE_SMA, PRICE_CLOSE, 2);

   bool golden = (fast2 <= slow2 && fast1 > slow1);
   bool dead   = (fast2 >= slow2 && fast1 < slow1);

   if(golden)
   {
      ClosePositions(OP_SELL);
      if(CountPositions(OP_BUY) == 0)
         if(OrderSend(_Symbol, OP_BUY, InpLots, Ask, 30, 0, 0, "GC", InpMagic, 0, clrBlue) < 0)
            Print("買い失敗 error=", GetLastError());
   }
   if(dead)
   {
      ClosePositions(OP_BUY);
      if(CountPositions(OP_SELL) == 0)
         if(OrderSend(_Symbol, OP_SELL, InpLots, Bid, 30, 0, 0, "DC", InpMagic, 0, clrRed) < 0)
            Print("売り失敗 error=", GetLastError());
   }
}

MQL5（MT5）コードをコピー

// ゴールデンクロスで買い・デッドクロスで売り（ドテン）の EA（MT5）
#include <Trade\Trade.mqh>

input int    InpFast  = 5;      // 短期 MA の期間
input int    InpSlow  = 20;     // 長期 MA の期間
input double InpLots  = 0.1;    // ロット
input ulong  InpMagic = 1001;   // マジックナンバー

CTrade   trade;
int      hFast = INVALID_HANDLE, hSlow = INVALID_HANDLE;
datetime lastBar = 0;

int OnInit()
{
   if(InpFast >= InpSlow) return INIT_PARAMETERS_INCORRECT;
   hFast = iMA(_Symbol, PERIOD_CURRENT, InpFast, 0, MODE_SMA, PRICE_CLOSE);
   hSlow = iMA(_Symbol, PERIOD_CURRENT, InpSlow, 0, MODE_SMA, PRICE_CLOSE);
   if(hFast == INVALID_HANDLE || hSlow == INVALID_HANDLE) return INIT_FAILED;
   trade.SetExpertMagicNumber(InpMagic);
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   IndicatorRelease(hFast);
   IndicatorRelease(hSlow);
}

// この EA のポジションを、指定した向きだけ決済する
void ClosePositions(ENUM_POSITION_TYPE type)
{
   for(int i = PositionsTotal() - 1; i >= 0; i--)
   {
      ulong ticket = PositionGetTicket(i);
      if(ticket == 0) continue;
      if(PositionGetString(POSITION_SYMBOL) != _Symbol || (ulong)PositionGetInteger(POSITION_MAGIC) != InpMagic) continue;
      if(PositionGetInteger(POSITION_TYPE) != type) continue;
      if(!trade.PositionClose(ticket))
         Print("決済失敗 ", trade.ResultRetcodeDescription());
   }
}

int CountPositions(ENUM_POSITION_TYPE type)
{
   int n = 0;
   for(int i = PositionsTotal() - 1; i >= 0; i--)
   {
      if(PositionGetTicket(i) == 0) continue;
      if(PositionGetString(POSITION_SYMBOL) == _Symbol && (ulong)PositionGetInteger(POSITION_MAGIC) == InpMagic
         && PositionGetInteger(POSITION_TYPE) == type)
         n++;
   }
   return n;
}

void OnTick()
{
   // 新しい足ができたときだけ判定する
   datetime t = iTime(_Symbol, PERIOD_CURRENT, 0);
   if(t == lastBar) return;

   double fast[], slow[];
   ArraySetAsSeries(fast, true);   // [0]=1本前、[1]=2本前
   ArraySetAsSeries(slow, true);
   if(CopyBuffer(hFast, 0, 1, 2, fast) < 2 || CopyBuffer(hSlow, 0, 1, 2, slow) < 2)
      return;   // まだ計算中なら次のティックで再挑戦
   lastBar = t;

   bool golden = (fast[1] <= slow[1] && fast[0] > slow[0]);
   bool dead   = (fast[1] >= slow[1] && fast[0] < slow[0]);

   if(golden)
   {
      ClosePositions(POSITION_TYPE_SELL);
      if(CountPositions(POSITION_TYPE_BUY) == 0 && !trade.Buy(InpLots, _Symbol, 0, 0, 0, "GC"))
         Print("買い失敗 ", trade.ResultRetcodeDescription());
   }
   if(dead)
   {
      ClosePositions(POSITION_TYPE_BUY);
      if(CountPositions(POSITION_TYPE_SELL) == 0 && !trade.Sell(InpLots, _Symbol, 0, 0, 0, "DC"))
         Print("売り失敗 ", trade.ResultRetcodeDescription());
   }
}