MQLで損切り・利確を pips で指定して注文する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
#property script_show_inputs
// 損切り・利確を pips で指定して成行注文するスクリプト（MT4）
input bool   InpBuy  = true;   // true=買い、false=売り
input double InpLots = 0.1;    // ロット
input double InpSL   = 20;     // 損切り（pips）
input double InpTP   = 40;     // 利確（pips）

double PipSize()
{
   return (_Digits == 3 || _Digits == 5) ? _Point * 10 : _Point;
}

void OnStart()
{
   RefreshRates();
   double pip  = PipSize();
   double stop = MarketInfo(_Symbol, MODE_STOPLEVEL) * _Point;   // 最小距離
   double slW  = MathMax(InpSL * pip, stop + _Point);
   double tpW  = MathMax(InpTP * pip, stop + _Point);
   double sl, tp, price;
   int    type;
   if(InpBuy) { type = OP_BUY;  price = Ask; sl = Bid - slW; tp = Bid + tpW; }
   else       { type = OP_SELL; price = Bid; sl = Ask + slW; tp = Ask - tpW; }
   sl = NormalizeDouble(sl, _Digits);
   tp = NormalizeDouble(tp, _Digits);

   int ticket = OrderSend(_Symbol, type, InpLots, price, 30, sl, tp);
   if(ticket < 0)
      Print("注文失敗 error=", GetLastError(), " sl=", sl, " tp=", tp);
   else
      Print("注文成功 ticket=", ticket, " sl=", sl, " tp=", tp);
}

MQL5（MT5）コードをコピー

#property script_show_inputs
// 損切り・利確を pips で指定して成行注文するスクリプト（MT5）
#include <Trade\Trade.mqh>

input bool   InpBuy  = true;   // true=買い、false=売り
input double InpLots = 0.1;    // ロット
input double InpSL   = 20;     // 損切り（pips）
input double InpTP   = 40;     // 利確（pips）

double PipSize()
{
   return (_Digits == 3 || _Digits == 5) ? _Point * 10 : _Point;
}

void OnStart()
{
   double pip  = PipSize();
   double ask  = SymbolInfoDouble(_Symbol, SYMBOL_ASK);
   double bid  = SymbolInfoDouble(_Symbol, SYMBOL_BID);
   double stop = (double)SymbolInfoInteger(_Symbol, SYMBOL_TRADE_STOPS_LEVEL) * _Point;   // 最小距離
   double slW  = MathMax(InpSL * pip, stop + _Point);
   double tpW  = MathMax(InpTP * pip, stop + _Point);

   CTrade trade;
   bool sent;
   if(InpBuy)
      sent = trade.Buy(InpLots, _Symbol, 0, NormalizeDouble(bid - slW, _Digits), NormalizeDouble(bid + tpW, _Digits));
   else
      sent = trade.Sell(InpLots, _Symbol, 0, NormalizeDouble(ask + slW, _Digits), NormalizeDouble(ask - tpW, _Digits));

   if(!sent || trade.ResultRetcode() != TRADE_RETCODE_DONE)
      Print("注文失敗 ", trade.ResultRetcode(), " ", trade.ResultRetcodeDescription());
   else
      Print("注文成功 deal=", trade.ResultDeal());
}