MQLで全ポジション（または特定の EA のポジション）を一括決済する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
#property script_show_inputs
// ポジションを一括決済するスクリプト（MT4）
input bool InpThisSymbol = true;   // true=このチャートの通貨ペアだけ
input int  InpMagic      = -1;     // マジックナンバー（-1 ならすべて）

void OnStart()
{
   int closed = 0;
   for(int i = OrdersTotal() - 1; i >= 0; i--)   // 後ろから回す
   {
      if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;
      if(OrderType() > OP_SELL) continue;   // 待機注文は除く
      if(InpThisSymbol && OrderSymbol() != _Symbol) continue;
      if(InpMagic >= 0 && OrderMagicNumber() != InpMagic) continue;

      RefreshRates();
      if(OrderClose(OrderTicket(), OrderLots(), OrderClosePrice(), 30))
         closed++;
      else
         Print("決済失敗 ticket=", OrderTicket(), " error=", GetLastError());
   }
   Print(closed, " 件決済しました");
}

MQL5（MT5）コードをコピー

#property script_show_inputs
// ポジションを一括決済するスクリプト（MT5）
#include <Trade\Trade.mqh>

input bool InpThisSymbol = true;   // true=このチャートの通貨ペアだけ
input long InpMagic      = -1;     // マジックナンバー（-1 ならすべて）

void OnStart()
{
   CTrade trade;
   int closed = 0;
   for(int i = PositionsTotal() - 1; i >= 0; i--)   // 後ろから回す
   {
      ulong ticket = PositionGetTicket(i);
      if(ticket == 0) continue;
      if(InpThisSymbol && PositionGetString(POSITION_SYMBOL) != _Symbol) continue;
      if(InpMagic >= 0 && PositionGetInteger(POSITION_MAGIC) != InpMagic) continue;

      if(trade.PositionClose(ticket))
         closed++;
      else
         Print("決済失敗 ticket=", ticket, " ", trade.ResultRetcodeDescription());
   }
   Print(closed, " 件決済しました");
}