MQLで保有中のポジション数を数える方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// この EA の買い・売りポジション数を数えて表示する（MT4）
input int InpMagic = 1001;   // マジックナンバー

// type：OP_BUY または OP_SELL
int CountPositions(int type)
{
   int n = 0;
   for(int i = OrdersTotal() - 1; i >= 0; i--)
   {
      if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;
      if(OrderSymbol() == _Symbol && OrderMagicNumber() == InpMagic && OrderType() == type)
         n++;
   }
   return n;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   Comment("買い：", CountPositions(OP_BUY), "　売り：", CountPositions(OP_SELL));
}

MQL5（MT5）コードをコピー

// この EA の買い・売りポジション数を数えて表示する（MT5）
input ulong InpMagic = 1001;   // マジックナンバー

// type：POSITION_TYPE_BUY または POSITION_TYPE_SELL
int CountPositions(ENUM_POSITION_TYPE type)
{
   int n = 0;
   for(int i = PositionsTotal() - 1; i >= 0; i--)
   {
      if(PositionGetTicket(i) == 0) continue;
      if(PositionGetString(POSITION_SYMBOL) == _Symbol
         && (ulong)PositionGetInteger(POSITION_MAGIC) == InpMagic
         && PositionGetInteger(POSITION_TYPE) == type)
         n++;
   }
   return n;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   Comment("買い：", CountPositions(POSITION_TYPE_BUY), "　売り：", CountPositions(POSITION_TYPE_SELL));
}