MQLで損切りを建値（エントリー価格）に移動する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// 含み益が出たら損切りを建値に移動する EA（MT4）
input double InpTrigger = 20;     // 建値に移す含み益（pips）
input double InpLock    = 1;      // 建値からずらす幅（pips）
input int    InpMagic   = 1001;   // 対象のマジックナンバー

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnTick()
{
   double pip = (_Digits == 3 || _Digits == 5) ? _Point * 10 : _Point;
   for(int i = OrdersTotal() - 1; i >= 0; i--)
   {
      if(!OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) continue;
      if(OrderSymbol() != _Symbol || OrderMagicNumber() != InpMagic) continue;
      double open = OrderOpenPrice();

      if(OrderType() == OP_BUY && Bid - open >= InpTrigger * pip)
      {
         double be = NormalizeDouble(open + InpLock * pip, _Digits);
         if(OrderStopLoss() < be - _Point / 2)
            if(!OrderModify(OrderTicket(), open, be, OrderTakeProfit(), 0))
               Print("建値移動 失敗 error=", GetLastError());
      }
      if(OrderType() == OP_SELL && open - Ask >= InpTrigger * pip)
      {
         double be = NormalizeDouble(open - InpLock * pip, _Digits);
         if(OrderStopLoss() == 0 || OrderStopLoss() > be + _Point / 2)
            if(!OrderModify(OrderTicket(), open, be, OrderTakeProfit(), 0))
               Print("建値移動 失敗 error=", GetLastError());
      }
   }
}

MQL5（MT5）コードをコピー

// 含み益が出たら損切りを建値に移動する EA（MT5）
#include <Trade\Trade.mqh>

input double InpTrigger = 20;     // 建値に移す含み益（pips）
input double InpLock    = 1;      // 建値からずらす幅（pips）
input ulong  InpMagic   = 1001;   // 対象のマジックナンバー

CTrade trade;

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnTick()
{
   double pip = (_Digits == 3 || _Digits == 5) ? _Point * 10 : _Point;
   for(int i = PositionsTotal() - 1; i >= 0; i--)
   {
      ulong ticket = PositionGetTicket(i);
      if(ticket == 0) continue;
      if(PositionGetString(POSITION_SYMBOL) != _Symbol || (ulong)PositionGetInteger(POSITION_MAGIC) != InpMagic) continue;
      double open = PositionGetDouble(POSITION_PRICE_OPEN);
      double cur  = PositionGetDouble(POSITION_PRICE_CURRENT);
      double sl   = PositionGetDouble(POSITION_SL);
      double tp   = PositionGetDouble(POSITION_TP);

      if(PositionGetInteger(POSITION_TYPE) == POSITION_TYPE_BUY && cur - open >= InpTrigger * pip)
      {
         double be = NormalizeDouble(open + InpLock * pip, _Digits);
         if(sl < be - _Point / 2 && !trade.PositionModify(ticket, be, tp))
            Print("建値移動 失敗 ", trade.ResultRetcodeDescription());
      }
      if(PositionGetInteger(POSITION_TYPE) == POSITION_TYPE_SELL && open - cur >= InpTrigger * pip)
      {
         double be = NormalizeDouble(open - InpLock * pip, _Digits);
         if((sl == 0 || sl > be + _Point / 2) && !trade.PositionModify(ticket, be, tp))
            Print("建値移動 失敗 ", trade.ResultRetcodeDescription());
      }
   }
}