MQLで保有ポジションの含み損益の合計を計算する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// この EA の含み損益の合計を表示し、目標・許容値でアラートを出す（MT4）
input int    InpMagic  = 1001;    // マジックナンバー
input double InpTarget = 5000;    // 目標利益（口座通貨）
input double InpMaxDD  = -3000;   // 許容損失（口座通貨・マイナス）

double TotalProfit()
{
   double sum = 0;
   for(int i = OrdersTotal() - 1; i >= 0; i--)
      if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES) && OrderSymbol() == _Symbol
         && OrderMagicNumber() == InpMagic && OrderType() <= OP_SELL)
         sum += OrderProfit() + OrderSwap() + OrderCommission();
   return sum;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   static bool notified = false;
   double p = TotalProfit();
   Comment("含み損益の合計：", DoubleToString(p, 0), " ", AccountCurrency());
   if(!notified && (p >= InpTarget || p <= InpMaxDD))
   {
      Alert(_Symbol, " 含み損益の合計が ", DoubleToString(p, 0), " になりました");
      notified = true;
   }
   if(p < InpTarget && p > InpMaxDD) notified = false;
}

MQL5（MT5）コードをコピー

// この EA の含み損益の合計を表示し、目標・許容値でアラートを出す（MT5）
input ulong  InpMagic  = 1001;    // マジックナンバー
input double InpTarget = 5000;    // 目標利益（口座通貨）
input double InpMaxDD  = -3000;   // 許容損失（口座通貨・マイナス）

double TotalProfit()
{
   double sum = 0;
   for(int i = PositionsTotal() - 1; i >= 0; i--)
      if(PositionGetTicket(i) > 0 && PositionGetString(POSITION_SYMBOL) == _Symbol
         && (ulong)PositionGetInteger(POSITION_MAGIC) == InpMagic)
         sum += PositionGetDouble(POSITION_PROFIT) + PositionGetDouble(POSITION_SWAP);
   return sum;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   static bool notified = false;
   double p = TotalProfit();
   Comment("含み損益の合計：", DoubleToString(p, 0), " ", AccountInfoString(ACCOUNT_CURRENCY));
   if(!notified && (p >= InpTarget || p <= InpMaxDD))
   {
      Alert(_Symbol, " 含み損益の合計が ", DoubleToString(p, 0), " になりました");
      notified = true;
   }
   if(p < InpTarget && p > InpMaxDD) notified = false;
}