MQLで今日の確定損益を計算する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// 今日の確定損益を表示する EA（MT4）
input int InpMagic = -1;   // マジックナンバー（-1 ならすべて）

double TodayProfit()
{
   datetime today = iTime(_Symbol, PERIOD_D1, 0);
   double sum = 0;
   for(int i = OrdersHistoryTotal() - 1; i >= 0; i--)
   {
      if(!OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) continue;
      if(OrderType() > OP_SELL || OrderCloseTime() < today) continue;
      if(InpMagic >= 0 && OrderMagicNumber() != InpMagic) continue;
      sum += OrderProfit() + OrderSwap() + OrderCommission();
   }
   return sum;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   Comment("今日の確定損益：", DoubleToString(TodayProfit(), 0), " ", AccountCurrency());
}

MQL5（MT5）コードをコピー

// 今日の確定損益を表示する EA（MT5）
input long InpMagic = -1;   // マジックナンバー（-1 ならすべて）

double TodayProfit()
{
   datetime today = iTime(_Symbol, PERIOD_D1, 0);
   double sum = 0;
   if(!HistorySelect(today, TimeCurrent() + 60)) return 0;
   for(int i = HistoryDealsTotal() - 1; i >= 0; i--)
   {
      ulong d = HistoryDealGetTicket(i);
      if(d == 0) continue;
      long entry = HistoryDealGetInteger(d, DEAL_ENTRY);
      if(entry != DEAL_ENTRY_OUT && entry != DEAL_ENTRY_INOUT && entry != DEAL_ENTRY_OUT_BY) continue;
      if(InpMagic >= 0 && HistoryDealGetInteger(d, DEAL_MAGIC) != InpMagic) continue;
      sum += HistoryDealGetDouble(d, DEAL_PROFIT) + HistoryDealGetDouble(d, DEAL_SWAP) + HistoryDealGetDouble(d, DEAL_COMMISSION);
   }
   return sum;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   Comment("今日の確定損益：", DoubleToString(TodayProfit(), 0), " ", AccountInfoString(ACCOUNT_CURRENCY));
}