MQLで直前の取引の勝ち負け（損益）を調べる方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// 直前の取引の損益と連敗数を表示する EA（MT4）
input int InpMagic = 1001;   // マジックナンバー

// 新しい順に見て、負けが何回続いているか
int LossStreak(double &lastProfit)
{
   lastProfit = 0;
   int streak = 0;
   datetime lastTime = 0;
   // 口座履歴は時刻順とは限らないので、新しい順に並べて調べる
   int n = OrdersHistoryTotal();
   datetime times[]; double profits[];
   ArrayResize(times, 0); ArrayResize(profits, 0);
   for(int i = 0; i < n; i++)
   {
      if(!OrderSelect(i, SELECT_BY_POS, MODE_HISTORY)) continue;
      if(OrderMagicNumber() != InpMagic || OrderSymbol() != _Symbol || OrderType() > OP_SELL) continue;
      int k = ArraySize(times);
      ArrayResize(times, k + 1); ArrayResize(profits, k + 1);
      times[k] = OrderCloseTime();
      profits[k] = OrderProfit() + OrderSwap() + OrderCommission();
   }
   for(int done = 0; done < ArraySize(times); done++)
   {
      int best = -1;
      for(int j = 0; j < ArraySize(times); j++)   // まだ見ていない中で最も新しいもの
         if(times[j] != 0 && (best < 0 || times[j] > times[best])) best = j;
      if(best < 0) break;
      if(lastTime == 0) { lastProfit = profits[best]; lastTime = times[best]; }
      if(profits[best] >= 0) break;
      streak++;
      times[best] = 0;
   }
   return streak;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   double last;
   int streak = LossStreak(last);
   Comment("直前の損益：", DoubleToString(last, 0), "　連敗数：", streak);
}

MQL5（MT5）コードをコピー

// 直前の取引の損益と連敗数を表示する EA（MT5）
input ulong InpMagic = 1001;   // マジックナンバー

// 新しい順に見て、負けが何回続いているか
int LossStreak(double &lastProfit)
{
   lastProfit = 0;
   int streak = 0;
   bool first = true;
   if(!HistorySelect(0, TimeCurrent() + 60)) return 0;
   for(int i = HistoryDealsTotal() - 1; i >= 0; i--)   // ディールは時刻順に並んでいる
   {
      ulong d = HistoryDealGetTicket(i);
      if(d == 0) continue;
      if(HistoryDealGetInteger(d, DEAL_ENTRY) != DEAL_ENTRY_OUT) continue;
      if((ulong)HistoryDealGetInteger(d, DEAL_MAGIC) != InpMagic || HistoryDealGetString(d, DEAL_SYMBOL) != _Symbol) continue;
      double p = HistoryDealGetDouble(d, DEAL_PROFIT) + HistoryDealGetDouble(d, DEAL_SWAP) + HistoryDealGetDouble(d, DEAL_COMMISSION);
      if(first) { lastProfit = p; first = false; }
      if(p >= 0) break;
      streak++;
   }
   return streak;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   Comment("");
}

void OnTick()
{
   double last;
   int streak = LossStreak(last);
   Comment("直前の損益：", DoubleToString(last, 0), "　連敗数：", streak);
}