MQLで成行で買い・売りの注文を出す方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
#property script_show_inputs
// 成行で買い（または売り）注文を出すスクリプト（MT4）
input bool   InpBuy   = true;   // true=買い、false=売り
input double InpLots  = 0.1;    // ロット
input int    InpMagic = 0;      // マジックナンバー

void OnStart()
{
   RefreshRates();
   int    type  = InpBuy ? OP_BUY : OP_SELL;
   double price = InpBuy ? Ask : Bid;
   int ticket = OrderSend(_Symbol, type, InpLots, price, 30, 0, 0, "script", InpMagic, 0, InpBuy ? clrBlue : clrRed);
   if(ticket < 0)
      Print("注文失敗 error=", GetLastError());
   else
      Print("注文成功 ticket=", ticket);
}

MQL5（MT5）コードをコピー

#property script_show_inputs
// 成行で買い（または売り）注文を出すスクリプト（MT5）
#include <Trade\Trade.mqh>

input bool   InpBuy   = true;   // true=買い、false=売り
input double InpLots  = 0.1;    // ロット
input ulong  InpMagic = 0;      // マジックナンバー

void OnStart()
{
   CTrade trade;
   trade.SetExpertMagicNumber(InpMagic);
   trade.SetDeviationInPoints(30);
   bool sent = InpBuy ? trade.Buy(InpLots) : trade.Sell(InpLots);
   uint rc = trade.ResultRetcode();
   if(!sent || (rc != TRADE_RETCODE_DONE && rc != TRADE_RETCODE_PLACED))
      Print("注文失敗 ", rc, " ", trade.ResultRetcodeDescription());
   else
      Print("注文成功 deal=", trade.ResultDeal(), " 価格=", trade.ResultPrice());
}