MQLで手持ちのインジケーターのサインを EA で読み取る方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// インジケーターのサイン（バッファ0=買い、1=売り）を読み取る EA（MT4）
input string InpIndicator = "MyArrow";   // インジケーターのファイル名（拡張子なし）
input int    InpBuyBuf    = 0;           // 買いサインのバッファ番号
input int    InpSellBuf   = 1;           // 売りサインのバッファ番号

datetime lastBar = 0;

bool HasSignal(double v)
{
   return v != 0 && v != EMPTY_VALUE;
}

int OnInit()
{
   return INIT_SUCCEEDED;
}

void OnTick()
{
   datetime t = iTime(_Symbol, PERIOD_CURRENT, 0);
   if(t == lastBar) return;
   lastBar = t;

   // パラメーターはインジケーターの input の順番どおりに書く（省略すると既定値）
   double buy  = iCustom(_Symbol, 0, InpIndicator, InpBuyBuf, 1);
   double sell = iCustom(_Symbol, 0, InpIndicator, InpSellBuf, 1);
   if(GetLastError() == 4072)
   {
      Print(InpIndicator, " を読み込めません。ファイル名とコンパイル済みか確認してください");
      return;
   }
   if(HasSignal(buy))  Alert(_Symbol, " 買いサイン");
   if(HasSignal(sell)) Alert(_Symbol, " 売りサイン");
}

MQL5（MT5）コードをコピー

// インジケーターのサイン（バッファ0=買い、1=売り）を読み取る EA（MT5）
input string InpIndicator = "MyArrow";   // インジケーターのファイル名（拡張子なし）
input int    InpBuyBuf    = 0;           // 買いサインのバッファ番号
input int    InpSellBuf   = 1;           // 売りサインのバッファ番号

int      hInd = INVALID_HANDLE;
datetime lastBar = 0;

bool HasSignal(double v)
{
   return v != 0 && v != EMPTY_VALUE;
}

int OnInit()
{
   // パラメーターは iCustom(銘柄, 時間足, 名前, パラメーター1, パラメーター2, …) の順に書く
   hInd = iCustom(_Symbol, PERIOD_CURRENT, InpIndicator);
   if(hInd == INVALID_HANDLE)
   {
      Print(InpIndicator, " を読み込めません error=", GetLastError());
      return INIT_FAILED;
   }
   return INIT_SUCCEEDED;
}

void OnDeinit(const int reason)
{
   IndicatorRelease(hInd);
}

void OnTick()
{
   datetime t = iTime(_Symbol, PERIOD_CURRENT, 0);
   if(t == lastBar) return;

   double buy[], sell[];
   if(CopyBuffer(hInd, InpBuyBuf, 1, 1, buy) < 1 || CopyBuffer(hInd, InpSellBuf, 1, 1, sell) < 1)
      return;   // 計算待ち
   lastBar = t;

   if(HasSignal(buy[0]))  Alert(_Symbol, " 買いサイン");
   if(HasSignal(sell[0])) Alert(_Symbol, " 売りサイン");
}