MQLでチャートの画像（スクリーンショット）を保存する方法（MT4・MT5）

MQL4（MT4）コードをコピー

#property strict
// エントリーしたらチャートの画像を保存する EA（MT4）
int lastCount = 0;

int Positions()
{
   int n = 0;
   for(int i = OrdersTotal() - 1; i >= 0; i--)
      if(OrderSelect(i, SELECT_BY_POS, MODE_TRADES) && OrderSymbol() == _Symbol && OrderType() <= OP_SELL)
         n++;
   return n;
}

void SaveShot()
{
   string t = TimeToString(TimeCurrent(), TIME_DATE | TIME_SECONDS);
   StringReplace(t, ".", "");
   StringReplace(t, ":", "");
   StringReplace(t, " ", "_");
   string file = "shots\\" + _Symbol + "_" + t + ".png";
   if(ChartScreenShot(0, file, 1280, 720))
      Print("保存しました：Files\\", file);
}

int OnInit()
{
   lastCount = Positions();
   return INIT_SUCCEEDED;
}

void OnTick()
{
   int now = Positions();
   if(now > lastCount) SaveShot();   // ポジションが増えた＝エントリー
   lastCount = now;
}

MQL5（MT5）コードをコピー

// エントリーしたらチャートの画像を保存する EA（MT5）
int lastCount = 0;

int Positions()
{
   int n = 0;
   for(int i = PositionsTotal() - 1; i >= 0; i--)
      if(PositionGetTicket(i) > 0 && PositionGetString(POSITION_SYMBOL) == _Symbol)
         n++;
   return n;
}

void SaveShot()
{
   string t = TimeToString(TimeCurrent(), TIME_DATE | TIME_SECONDS);
   StringReplace(t, ".", "");
   StringReplace(t, ":", "");
   StringReplace(t, " ", "_");
   string file = "shots\\" + _Symbol + "_" + t + ".png";
   if(ChartScreenShot(0, file, 1280, 720))
      Print("保存しました：Files\\", file);
}

int OnInit()
{
   lastCount = Positions();
   return INIT_SUCCEEDED;
}

void OnTick()
{
   int now = Positions();
   if(now > lastCount) SaveShot();   // ポジションが増えた＝エントリー
   lastCount = now;
}