MQLでローソク足のデータを CSV ファイルに書き出す方法（MT4・MT5）

MQL4・MQL5 共通コードをコピー

#property strict
#property script_show_inputs
// 直近 N 本のローソク足を CSV に書き出すスクリプト
input int InpBars = 1000;   // 書き出す本数

void OnStart()
{
   string file = _Symbol + "_" + EnumToString((ENUM_TIMEFRAMES)_Period) + ".csv";
   int h = FileOpen(file, FILE_WRITE | FILE_CSV | FILE_ANSI, ',');
   if(h == INVALID_HANDLE)
   {
      Print("ファイルを開けません error=", GetLastError());
      return;
   }
   FileWrite(h, "time", "open", "high", "low", "close", "volume");
   int n = MathMin(InpBars, iBars(_Symbol, PERIOD_CURRENT) - 1);
   for(int i = n; i >= 1; i--)   // 古い足から順に（確定足だけ）
      FileWrite(h, TimeToString(iTime(_Symbol, PERIOD_CURRENT, i)),
                DoubleToString(iOpen(_Symbol, PERIOD_CURRENT, i), _Digits),
                DoubleToString(iHigh(_Symbol, PERIOD_CURRENT, i), _Digits),
                DoubleToString(iLow(_Symbol, PERIOD_CURRENT, i), _Digits),
                DoubleToString(iClose(_Symbol, PERIOD_CURRENT, i), _Digits),
                iVolume(_Symbol, PERIOD_CURRENT, i));
   FileClose(h);
   Print(n, " 本を Files フォルダの ", file, " に書き出しました（ファイル→データフォルダを開く で確認）");
}